10/Ago/05 13:22
Re: DEVOLVER UN VALOR BAJO DOS CONDICIONANTES
Hola, lo puedes lograr con una formula matricial, te recomiendo que leas la ayuda de excel. Te doy una breve explicacion:
Las formulas matriciales son similares a las formulas NO matriciales(NORMAL) , con la ventaja que las formulas matriciales te permite "REPETIR" una formula NORMAL dentro de una matriz de datos, algo asi como que si haces una formula NORMAL que sirve para una fila, al convertirla en Matricial puedes hacer que esa formula se aplique a todas las filas de una matriz, y ya con los resultados de todas las filas, entonces puedas por ejemplo SUMARLAS. Checa lo siguiente
En el ejemplo la columna A contiene los meses en las celdas A2:A13, el año en B2:B13 y los importes a sumar de C2:C13
A____B_____C
Mes Año Importe
1 2004 1100
2 2004 1200
3 2004 1300
1 2005 1400
2 2005 1500
3 2005 1600
1 2004 1700
2 2004 1800
3 2004 1900
1 2005 2000
2 2005 2100
3 2005 2200
Suponemos que tenemos los siguientes datos:
Celda E2 = 1 (Aqui capturamos el mes que queremos considerar)
Celda F2 = 2004 (Aqui ponemos el año que queremos considerar)
Celda G2 = Aqui pondremos la formula tomando como base las 2 celdas anteriores
En una formula NORMAL aplicable solo a la fila 2 seria algo asi:
=(SI($A$2=E2,SI($B$2=F2,$C$2,0),0)
Esta formula condiciona a que nos de el valor si la celda A2 tiene el mismo mes capturado en E2 y si ademas la celda B2 tiene el mismo año capturado en la celda F2.
Bueno, pues ahora necesitariamos sumar todos los resultados obtenidos por esta formula como si se copiara en cada una de las filas 2 a la 13. Esto es precisamente loq ue puede hacer una formula matricial.
Ahora vamos a convertir la formula NORMAL a una MATRICIAL, seria cambiando todas las referencias a las matrices de datos correspondientes, y ademas indicandole a excel que es una formula matricial agregandole unas llaves {} al principio y final de la formula.
Tomando como base la formula anterior ahora cambiamos referecias:
=SI($A$2:$A$13=E2,SI($B$2:$B$13=F2,$C$2:$C$13,0),0)
Ahora necesitamos indicarle a la formula que sumara esos resultados de cada fila:
=SUMA(SI($A$2:$A$13=E2,SI($B$2:$B$13=F2,$C$2:$C$13,0),0))
Y para terminar indicamos de que se trata de una formula matricial capturando la formula como la anterior, y en lugar de dar ENTER debemos darle CTRL+MAYUSC+ENTER, de esta manera excel interpreta que es una formula matricial y automaticamente se agregan las llaves {}.
Ahora prueba cambiando los valores de mes y año y observa como cambia el resultado de la formula matricial.
Si deseas saber cuanto hay en cada mes solo copia las 3 celdas E2, F2 y G2 hacia abajo y a cada fila le cambias el mes y el año segun lo necesites, saludos.
Saludos.
Si quieres triunfar primero debes vencer tus miedos.